#!/usr/bin/awk -f
# HAT TRICK
# (C) 2022 C. Duckworth

# ht.awk converts mostly-html (with some conveniences) to actual html

function bufpush(s) {
    BUF = BUF (BUF ? "\n" : "") s;
}

function buflush() {
    if (BUF) print BUF;
    BUF = "";
    if (tag && (tag != "html") && (tag != "raw"))
        print "</" tag ">";
}

function esc(t) {
    # This is of much more limited utility than I initially realized.
    gsub(/&/, "\\&amp;", t);
    gsub(/</, "\\&lt;", t);
    gsub(/>/, "\\&gt;", t);
    sub(/^ /, "\\&nbsp;", t);
    return t;
}

/^;/ { sub(/^;/,""); print "<!--", esc($0), "-->"; next; }

/^</ { # Raw HTML
    if (! (tag == "html")) tag = "html";
    bufpush($0);
    next;
}

/^```$/ { # Raw block
    if (! (tag == "raw")) {
        tag = "raw";
        getline;
        bufpush("<pre><code>" $0);
    } else {
        bufpush("</code></pre>");
        buflush();
        tag = "";
    }
    next;
}

/^=>/ { # Links (Gemini-style)
    if (tag == "raw") next;
    link = "<a href=\"" esc($2) "\">" $3;
    for (i=4;i<=NF;i++) link = link " " $i;
    link = link "</a>";
    bufpush(link);
    next;
}

/^-/ { # Unordered lists
    if (tag == "raw") next;
    if (! (tag == "ul")) tag = "ul";
    sub(/^-[ \t]*/, "<li>");
}

/^[0-9]+\./ { # Ordered lists
    if (tag == "raw") next;
    if (! (tag == "ol")) tag = "ol";
    sub(/^[0-9]+\.[ \t]/, "<li>");
}

/^>/ { # Blockquotes
    if (tag == "raw") next;
    if (! (tag == "blockquote")) tag = "blockquote";
    sub(/^>[ \t]*/,"");
}

/^#+/ { # Headers
    if (tag == "raw") next;
    match($0, /^#+/);
    if (! (tag == "h" RLENGTH)) {
        buflush();
        tag = "h" RLENGTH;
    }
    sub(/^#+[ \t]*/,"");
}

/^$/ {
    if (tag == "raw") next;
    buflush();
    tag = "";
}

/./ {
    if (! tag) tag = "p";
    if (! BUF) bufpush("<" tag ">");
    if (tag == "raw") $0 = esc($0);
    bufpush($0);
}

END { buflush(); }