#!/usr/bin/awk -f
# HAT TRICK
# (C) 2022 C. Duckworth

# ht.awk converts mostly-html (with some conveniences) to actual html

function bufpush(s) {
    BUF = BUF (BUF ? "\n" : "") s;
}

function buflush() {
    if (BUF) print BUF;
    BUF = "";
    if (tag && (tag != "html")) print "</" tag ">";
}

function esc(t) {
    # This is of much more limited utility than I initially realized.
    gsub(/&/, "\\&amp;", t);
    gsub(/</, "\\&lt;", t);
    gsub(/>/, "\\&gt;", t);
    return t;
}

/^;/ { sub(/^;/,""); print "<!--", esc($0), "-->"; next; }

/^</ { # Raw HTML
    if (! (tag == "html")) tag = "html";
    bufpush($0);
    next;
}

/^=>/ { # Links (Gemini-style)
    link = "<a href=\"" esc($2) "\">" $3;
    for (i=4;i<=NF;i++) link = link " " $i;
    link = link "</a>";
    bufpush(link);
    next;
}

/^-/ { # Unordered lists
    if (! (tag == "ul")) tag = "ul";
    sub(/^-[ \t]*/, "<li>");
}

/^[0-9]+\./ { # Ordered lists
    if (! (tag == "ol")) tag = "ol";
    sub(/^[0-9]+\.[ \t]/, "<li>");
}

/^>/ { # Blockquotes
    if (! (tag == "blockquote")) tag = "blockquote";
    sub(/^>[ \t]*/,"");
}

/^#+/ { # Headers
    match($0, /^#+/);
    if (! (tag == "h" RLENGTH)) {
        buflush();
        tag = "h" RLENGTH;
    }
    sub(/^#+[ \t]*/,"");
}

/^$/ {
    buflush();
    tag = "";
}

/./ {
    if (! tag) tag = "p";
    if (! BUF) bufpush("<" tag ">");
    bufpush($0);
}

END { buflush(); }