1 files changed, 151 insertions, 0 deletions

@@ -0,0 +1,151 @@
+#!/bin/sh
+{ dummy=":" "exec" "awk" "-f" "$0" "$@"; } # -*- awk -*-
+
+#: # h1
+#: ## h2
+#: ### h3
+#: => link
+#: * list
+#: > quote
+#: ``` ... ```  verbatim
+
+BEGIN { # configuration
+        if (!to) to = "html" # default: html
+
+        if (to == "html") {
+                opener["verbatim"] = "<pre><code>"
+                closer["verbatim"] = "</code></pre>\n"
+                linefmt["verbatim"] = "%s\n"
+                verbatim_esc[1] = "&"
+                verbatim_repl[1] = "&amp;"
+                verbatim_esc[2] = "<"
+                verbatim_repl[2] = "&lt;"
+                verbatim_esc[3] = ">"
+                verbatim_repl[3] = "&gt;"
+                headerfmt[1] = "<h1>%s</h1>\n"
+                headerfmt[2] = "<h2>%s</h2>\n"
+                headerfmt[3] = "<h3>%s</h3>\n"
+                linkfmt = "<a href=\"%s\">%s</a>\n"
+                link_block = 0
+                opener["quote"] = "<blockquote>"
+                closer["quote"] = "</blockquote>\n"
+                linefmt["quote"] = "%s\n"
+                opener["paragraph"] = "<p>"
+                closer["paragraph"] = "</p>\n"
+                linefmt["paragraph"] = "%s\n"
+                paragraph_collapse = 0 # turn \n to ' ' in paragraphs
+                # consider: paragraph_fold-- <w>, 0 (do nothing), -1 (collapse)
+                collapse_blanks = 1
+                opener["list"] = "<ul>\n"
+                closer["list"] = "</ul>\n"
+                linefmt["list"] = "<li>%s</li>\n"
+                opener["linklist"] = "<ul class=\"linklist\">\n"
+                closer["linklist"] = "</ul>\n"
+                linefmt["linklist"] = "<li><a href=\"%s\">%s</a></li>\n"
+        } else if (to == "gemini") {
+                opener["verbatim"] = "```\n"
+                closer["verbatim"] = "```"
+                linefmt["verbatim"] = "%s\n"
+                headerfmt[1] = "# %s\n"
+                headerfmt[2] = "## %s\n"
+                headerfmt[3] = "### %s\n"
+                linkfmt = "=> %s %s\n"
+                link_block = 1
+                opener["quote"] = ""
+                closer["quote"] = ""
+                linefmt["quote"] = "> %s\n"
+                opener["paragraph"] = ""
+                closer["paragraph"] = ""
+                linefmt["paragraph"] = "%s\n"
+                paragraph_collapse = 1 # turn \n to ' ' in paragraphs
+                # consider: paragraph_fold-- <w>, 0 (do nothing), -1 (collapse)
+                collapse_blanks = 0
+                opener["list"] = "\n"
+                closer["list"] = ""
+                linefmt["list"] = "* %s\n"
+                opener["linklist"] = "\n"
+                closer["linklist"] = ""
+                linefmt["linklist"] = "=> %s %s\n"
+        } else die("Unknown `to' type: `" to "'")
+}
+
+/^```/ {
+        bl = BLOCK
+        close_block()
+        if (bl != "verbatim") BLOCK = "verbatim"
+        bl = ""
+        next
+}
+
+BLOCK == "verbatim" {
+        for (s in verbatim_esc) gsub(verbatim_esc[s], verbatim_repl[s])
+        bufpush($0 "\n")
+        next
+}
+
+/^#/ {
+        close_block()
+        match($0, /^#+/)
+        bufpush(sprintf(headerfmt[RLENGTH], collect(2)))
+        BLOCK = "header"
+        next
+}
+
+/^=>/ {
+        if (BLOCK == "paragraph" && !link_block)
+                bufpush(sprintf(linkfmt, $2, collect(3)))
+        if (BLOCK != "linklist") close_block()
+        BLOCK = "linklist"
+        bufpush(sprintf(linefmt[BLOCK], $2, collect(3)))
+        next
+}
+
+/^\*/ {
+        if (BLOCK != "list") close_block()
+        BLOCK = "list"
+        bufpush(sprintf(linefmt[BLOCK], collect(2)))
+        next
+}
+
+/^>/ {
+        if (BLOCK != "quote") close_block()
+        BLOCK = "quote"
+        bufpush(sprintf(linefmt[BLOCK], collect(2)))
+        next
+}
+
+/^$/ {
+        if (BLOCK == "verbatim") bufpush("\n")
+        else close_block()
+        next
+}
+
+{
+        if (BLOCK != "paragraph") close_block()
+        BLOCK = "paragraph"
+        bufpush(sprintf(linefmt[BLOCK], $0))
+        next
+}
+
+END { close_block(); printf "\n" }
+
+function close_block () {
+        if (!BLOCK) {
+                if (collapse_blanks) return
+                else printf "\n"
+        }
+        if (BLOCK == "paragraph" && paragraph_collapse)
+                gsub(/\n/, " ", BUFFER)
+        printf("%s%s%s", opener[BLOCK], BUFFER, closer[BLOCK])
+        BUFFER = BLOCK = ""
+}
+
+function collect (begin, end,   out) {
+        for (f = (begin?begin:1); f <= (end?end:NF); f++)
+                out = out (out?" ":"") $f
+        return out
+}
+
+function bufpush (str) {
+        BUFFER = BUFFER str
+}