1 files changed, 167 insertions, 0 deletions

@@ -1,5 +1,106 @@
 ;;; +org.el --- -*- lexical-binding: t -*-
 
+;;; Org Return DWIM
+;; [[https://github.com/alphapapa/unpackaged.el][unpackaged]] and [[http://kitchingroup.cheme.cmu.edu/blog/2017/04/09/A-better-return-in-org-mode/][kitchin]]
+
+(defun +org-element-descendant-of (type element)
+  "Return non-nil if ELEMENT is a descendant of TYPE.
+TYPE should be an element type, like `item' or `paragraph'.
+ELEMENT should be a list like that returned by `org-element-context'."
+  ;; MAYBE: Use `org-element-lineage'.
+  (when-let* ((parent (org-element-property :parent element)))
+    (or (eq type (car parent))
+        (+org-element-descendant-of type parent))))
+
+(defun +org-return-dwim (&optional prefix)
+  "A helpful replacement for `org-return'.
+With PREFIX, call `org-return'."
+  (interactive "P")
+  ;; Auto-fill if enabled
+  (when auto-fill-function
+    (dolist (func (ensure-list auto-fill-function))
+      (funcall func)))
+  (cond
+   (prefix                              ; Handle prefix
+    (pcase prefix
+      ('(4) (newline))
+      ('(16) (newline 2))
+      (_ (newline prefix))))
+   ((and org-return-follows-link        ; Open link
+         (eq 'link (car (org-element-context))))
+    (org-open-at-point-global))
+   ((org-at-heading-p)                  ; Open a line after a heading
+    (let ((heading-start (org-entry-beginning-position)))
+      (goto-char (org-entry-end-position))
+      (cond ((and (org-at-heading-p)
+                  (= heading-start (org-entry-beginning-position)))
+             ;; Entry ends on its heading, so add 2 newlines
+             (end-of-line)
+             (newline 2))
+            (t
+             ;; Entry ends after its heading, so back up
+             (forward-line -1)
+             (end-of-line)
+             (when (org-at-heading-p)
+               (forward-line)
+               (newline)
+               (forward-line -1))
+             (while (not (looking-back (rx (repeat 3 (seq (optional blank) "\n")))
+                                       nil))
+               (newline))
+             (forward-line -1)))))
+   ((org-at-item-checkbox-p)            ; Insert a new checkbox item
+    (end-of-line)
+    (org-insert-todo-heading nil))
+   ((org-in-item-p)                     ; Insert a new list item
+    (let* ((context (org-element-context))
+           (first-item-p (eq 'plain-list (car context)))
+           (itemp (eq 'item (car context)))
+           (emptyp (or
+                    ;; This (regular) list item is empty
+                    (eq (org-element-property :contents-begin context)
+                        (org-element-property :contents-end context))
+                    ;; This (definition) list item is empty
+                    (looking-at " *::")))
+           (item-child-p (+org-element-descendant-of 'item context)))
+      (cond ((and itemp emptyp)
+             (delete-region (line-beginning-position) (line-end-position))
+             (newline))
+            ((or first-item-p
+                 (and itemp (not emptyp))
+                 item-child-p)
+             (org-end-of-item)
+             (org-insert-item))
+            (t
+             (delete-region (line-beginning-position) (line-end-position))
+             (newline)))))
+   ((and (fboundp 'org-inlinetask-in-task-p) ; Don't insert a new heading with
+         (org-inlinetask-in-task-p))         ; inline tasks
+    (org-return))
+   ((org-at-table-p)                    ; Insert a new org-table row
+    (cond ((save-excursion
+             (beginning-of-line)
+             (cl-loop with end = (line-end-position)
+                      for cell = (org-element-table-cell-parser)
+                      always (equal (org-element-property :contents-begin cell)
+                                    (org-element-property :contents-end cell))
+                      while (re-search-forward "|" end t)))
+           ;; Empty row: end the table
+           (delete-region (line-beginning-position) (line-end-position))
+           (org-return))
+          (t
+           ;; Non-empty row
+           (org-return))))
+   (t                                   ; Otherwise---just call `org-return'.
+    (org-return))))
+
+(defun +org-table-copy-down|+org-return (&optional n)
+  "Call `org-table-copy-down' or `+org-return' depending on context."
+  (interactive "P")
+  (if (org-table-check-inside-data-field 'noerror)
+      (org-table-copy-down (or n 1))
+    (+org-return-dwim n)))
+
 ;;; Copy org trees as HTML
 
 ;; Thanks to Oleh Krehel, via [[https://emacs.stackexchange.com/questions/54292/copy-results-of-org-export-directly-to-clipboard][this StackExchange question]].
@@ -41,4 +142,70 @@ and POST-PROCESS are passed to `org-export-to-file'."
                        ("—" "---"))))
         (replace-match replace nil nil)))))
 
+;;; A ... different ... `org-open-at-point-dwim'
+;; I honestly don't remember what the difference is between this and the
+;; O.G. one is.. hopefully this one fixes annoying stupid problems.
+
+(defun +org-open-at-point-dwim (&optional arg)
+  "Open thing at point, or if there isn't something, list things."
+  (interactive "P")
+  (save-excursion
+    (let* ((this-char-type (org-element-type (org-element-context)))
+           (prev-char-type (ignore-errors
+                             (save-excursion
+                               (backward-char)
+                               (org-element-type (org-element-context)))))
+           (types '(citation citation-reference clock comment comment-block
+                             footnote-definition footnote-reference headline
+                             inline-src-block inlinetask keyword link
+                             node-property planning src-block timestamp))
+           (type this-char-type))
+      (when (and (memq this-char-type types) (memq prev-char-type types))
+        (backward-char)
+        (setq type prev-char-type))                  ; what the fuckckckckck
+      ;; Okay, so this ^ is pretty janky and doesn't /really/ work that well,
+      ;; especially on DEADLINE (and probably SCHEDULED) lines.  However, since
+      ;; I really just want to open the list of URLs /most of the time/, I'm
+      ;; fixing it like this instead.
+      (unless (and (memq type types)
+                   (ignore-errors (org-open-at-point arg)
+                                  t))
+        (while (not
+                (progn
+                  (org-back-to-heading)
+                  (car (org-offer-links-in-entry (current-buffer) (point) 1))))
+          (org-up-heading-all 1))
+        (org-open-at-point arg)))))
+
+;;; Skip invisible shit when moving around
+(defun +org-ignore-invisible (fn &rest r)
+  ":around ADVICE to ignore invisible text in `org-mode' buffers."
+  ;; TODO: generalize to all modes
+  (cond ((and (derived-mode-p #'org-mode)
+              (org-invisible-p))
+         (while (org-invisible-p)
+           (forward-char))
+         (apply fn r))
+        (t (apply fn r))))
+
+;;; Faces
+
+;;; Better org faces
+;; see `org-emphasis-alist'
+
+(defface org-bold '((t (:weight bold)))
+  "Bold face in `org-mode' documents.")
+
+(defface org-italic '((t (:slant italic)))
+  "Italic face in `org-mode' documents.")
+
+(defface org-underline '((t (:underline t)))
+  "Underline face in `org-mode' documents.")
+
+(defface org-strikethrough '((t (:strike-through t)))
+  "Strike-through face for `org-mode' documents.")
+
+;; `org-verbatim' and `org-code' are apparently already things, so we skip them
+;; here.
+
 (provide '+org)