Initial commit

I'm doing content + generation in this ... who knows if it's smart, lol.

1 files changed, 79 insertions, 0 deletions

@@ -0,0 +1,79 @@
+#!/usr/bin/awk -f
+# HAT TRICK
+# (C) 2022 C. Duckworth
+
+# ht.awk converts mostly-html (with some conveniences) to actual html
+
+function bufpush(s) {
+    BUF = BUF (BUF ? "\n" : "") s;
+}
+
+function buflush() {
+    if (BUF) print BUF;
+    BUF = "";
+    if (tag && (tag != "html")) print "</" tag ">";
+}
+
+function esc(t) {
+    gsub(/&/, "\\&amp;", t);
+    gsub(/</, "\\&lt;", t);
+    gsub(/>/, "\\&gt;", t);
+    return t;
+}
+
+/^;/ { sub(/^;/,""); print "<!--", esc($0), "-->"; next; }
+
+/^</ { # Raw HTML
+    if (! (tag == "html")) tag = "html";
+    bufpush($0);
+    next;
+}
+
+/^=>/ { # Links (Gemini-style)
+    link = "<a href=\"" esc($2) "\">" esc($3);
+    for (i=4;i<=NF;i++) link = link " " esc($i);
+    link = link "</a>";
+    bufpush(link);
+    next;
+}
+
+/^-/ { # Unordered lists
+    if (! (tag == "ul")) tag = "ul";
+    esc($0);
+    sub(/^-[ \t]*/, "<li>");
+}
+
+/^[0-9]+\./ { # Ordered lists
+    if (! (tag == "ol")) tag = "ol";
+    esc($0);
+    sub(/^[0-9]+\.[ \t]/, "<li>");
+}
+
+/^>/ { # Blockquotes
+    if (! (tag == "blockquote")) tag = "blockquote";
+    sub(/^>[ \t]*/,"");
+    esc($0);
+}
+
+/^#+/ { # Headers
+    match($0, /^#+/);
+    if (! (tag == "h" RLENGTH)) {
+        buflush();
+        tag = "h" RLENGTH;
+    }
+    sub(/^#+[ \t]*/,"");
+    esc($0);
+}
+
+/^$/ {
+    buflush();
+    tag = "";
+}
+
+/./ {
+    if (! tag) tag = "p";
+    if (! BUF) bufpush("<" tag ">");
+    bufpush($0);
+}
+
+END { buflush(); }